スピンロック

x86の場合、データ交換命令xchgはメモリーバリア機能を持っており、複数のCPUコアで実行された場合は相互にバスをロックし、キャッシュを更新する動作を合わせて実行する。

従ってx86/x64アーキテクチャーにおいては、メモリーアクセスの順序保証が必要な場合でも、殆どの場合は明示的なメモリーバリア命令を使わずに済む。

RAM上に確保されたstat_lockをフラグに用い、0か1かで判断する場合の例を以下に示す。

stat_lock:
    dd      0

spin_lock:
    mov     eax, 1
spin_lock_loop:
    xchg    eax, [stat_lock]
    test    eax, eax
    jnz     spin_lock_loop
    ret

spin_unlock:
    xor     eax, eax
    xchg    eax, [stat_lock]
    ret

上のspin_lock処理は、xchg命令でstat_lockの内容をeaxに取得すると同時に、stat_lockに1を代入する。結果のeaxが0なら他に使っている処理はないためそのまま終了するが、0以外なら他が使用中であるので、0になるまでループで処理を繰り返す。

上のspin_unlockはstat_lockに0を代入する処理である。アトミックかどうかだけ考えればxchgではなくmovでも良さそうに見えるが、実は良くない。xchg命令のメモリーバリア機能を使わないと、マルチプロセッサー時に正常に全CPUコアに反映されて見えない現象が生じるからである。

ARMの場合もx86と基本的に変わらないが、明示的にメモリーバリアーの命令を使用する必要がある。

ARMv7アーキテクチャー以降でも使用可能な手法は次のとおりである。

spin_lock/spin_unlock共に、予めr1にロックフラグに使用するメモリーのアドレスが格納されているものとする。

spin_lock:
    mov     r0, #1
spin_lock_loop:
    ldrex   r2, [r1]
    cmp     r2, #0
    wfene
    strexeq r2, r0, [r1]
    cmpeq   r2, #0
    bne     spin_lock_loop
    dmb
    bx      lr

spin_unlock:
    mov     r0, #0
    dmb
    str     r0, [r1]
    dsb
    sev
    bx      lr

なお、「bx lr」は「mov pc, lr」でもよい。どちらもサブルーチンから戻るための命令である。